VC2005/2008运行库Error1935的解决方法

这是一个极其罕见的故障。

安装iTunes时出现一段错误，显示VC2005支持库安装失败。单独安装也不行。百度了一下，有以下几种解决方法：

1. 换一个VC2005的版本
2. 找到Windows Modules Installer服务，将其打开
3. 关闭各种杀毒软件
4. 把 HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\RegistrySizeLimit 设置为0xffffffff

当然，这些方法似乎都不管用。最终，找到一个链接见此

为了方便阅读，请允许我将它翻译过来。

1. 下载SubInACL工具并安装，默认情况下，他会安装在 C:\Program Files\Windows Resource Kits\Tools
2. 打开命令提示符。如果你正在使用Windows XP及以下的操作系统，请使用 开始菜单 – 运行，键入 cmd 后回车。如果你正在使用Windows Vista/7/8/10及以上操作系统，请使用 开始菜单 – 所有程序 – 附件 ，右键点击 命令提示符 ，选择 使用管理员身份运行。
3. 在cmd窗口中，输入 notepad.exe reset.cmd 然后选择“是”
4. 将以下代码复制到记事本中。

@echo off
title Resetting ACLs...

setlocal

echo.
echo Determine whether we are on an 32 or 64 bit machine
echo.

if "%PROCESSOR_ARCHITECTURE%"=="x86" if "%PROCESSOR_ARCHITEW6432%"=="" goto x86

set ProgramFilesPath=%ProgramFiles(x86)%

goto startResetting

:x86

set ProgramFilesPath=%ProgramFiles%

:startResetting

echo.

if exist "%ProgramFilesPath%\Windows Resource Kits\Tools\subinacl.exe" goto filesExist

echo ***ERROR*** - Could not find file %ProgramFilesPath%\Windows Resource Kits\Tools\subinacl.exe. Double-check that SubInAcl is correctly installed and re-run this script.
goto END

:filesExist

pushd "%ProgramFilesPath%\Windows Resource Kits\Tools"

echo. 
echo Resetting ACLs...
echo (this may take several minutes to complete)
echo. 
echo IMPORTANT NOTE: For this script to run correctly, you must change
echo the values named YOURUSERNAME to be the Windows user account that
echo you are logged in with.
echo.
echo ==========================================================================
echo. 
echo. 
subinacl.exe /subkeyreg HKEY_CURRENT_USER /grant=administrators=f /grant=system=f /grant=restricted=r /grant=YOURUSERNAME=f /setowner=administrators > %temp%\subinacl_output.txt
echo. 
echo. 
subinacl.exe /keyreg HKEY_CURRENT_USER /grant=administrators=f /grant=system=f /grant=restricted=r /grant=YOURUSERNAME=f /setowner=administrators >> %temp%\subinacl_output.txt
echo. 
echo. 
subinacl.exe /subkeyreg HKEY_LOCAL_MACHINE /grant=administrators=f /grant=system=f /grant=users=r /grant=everyone=r /grant=restricted=r /setowner=administrators >> %temp%\subinacl_output.txt
echo. 
echo. 
subinacl.exe /keyreg HKEY_LOCAL_MACHINE /grant=administrators=f /grant=system=f /grant=users=r /grant=everyone=r /grant=restricted=r /setowner=administrators >> %temp%\subinacl_output.txt
echo. 
echo. 
subinacl.exe /subkeyreg HKEY_CLASSES_ROOT /grant=administrators=f /grant=system=f /grant=users=r /setowner=administrators >> %temp%\subinacl_output.txt
echo. 
echo. 
subinacl.exe /keyreg HKEY_CLASSES_ROOT /grant=administrators=f /grant=system=f /grant=users=r /setowner=administrators >> %temp%\subinacl_output.txt
echo. 
echo. 
echo System Drive...
subinacl.exe /subdirectories %ProgramFilesPath%\ /grant=administrators=f /grant=system=f /grant=users=e >> %temp%\subinacl_output.txt
echo. 
echo. 
echo Windows Directory...
subinacl.exe /subdirectories %windir%\ /grant=administrators=f /grant=system=f /grant=users=e >> %temp%\subinacl_output.txt
echo. 
echo. 
echo ==========================================================================
echo. 
echo FINISHED.
echo. 
echo Press any key to exit . . .
pause >NUL

popd

:END

endlocal

5.把上面的YOURUSERNAME修改为当前你登陆的用户名（提示：你可以在任务管理器中看到这个用户名）

6.保存，然后关闭记事本窗口

7.在命令提示符窗口中输入 reset.cmd 并回车。耐心等待运行完成。

8.再次安装VC2005/2008 etc.